Maple calculations

The computations below were done in Maple 12. The parameters a, b, c, etc. are initially the Behrend sphere densities (e.g. a is the proportion of points with no 2s that lie in the set), but when one converts from the X's to the Y's, they are the Behrend sphere counts (i.e. a is now the number of points with no 2s that lie in the set).

with(Optimization);

A3 := 8*a + 12*b + 6*c + d;

A4 := 16*a+32*b+24*c+8*d+e;

A5 := 32*a+80*b+80*c+40*d+10*e+f;

A6 := 64*a+192*b+240*c+160*d+60*e+12*f+g;

A7 := 128*a+448*b+672*c+560*d+280*e+84*f+14*g+h;

X1 := {2*a+b <= 2};

X2 := {4*a+2*b+c <= 4, 2*a+c <= 2, 2*b+c <= 2, c <= 1};

X3 := {op(X2), op(subs([a=b,b=c,c=d],X2)), 8*a+6*b+6*c+2*d<=11, 4*a+4*b+3*c+d<=6, 7*a+3*b+3*c+d <= 7, 4*a+6*c+2*d<=7, 6*a+3*c+d<=5, 2*a+d <= 2};

This comes from the linear inequalities obeyed by the 3D extremals.

X4 := {op(X3), op(subs([a=b,b=c,c=d,d=e],X3)), op(subs([b=c,c=e],X2))};

Y4 := subs([a=a/16,b=b/32,c=c/24,d=d/8],X4);

LPSolve(a+b+c+d+e,{op(Y4),e=1},assume=nonnegint,depthlimit=100,maximize);

[39, [a = 8, b = 16, c = 12, d = 2, e = 1]]

This, together with the bound [math]\displaystyle{ c'_4=43 }[/math], implies that [math]\displaystyle{ a+b+c+d+5e \leq 43 }[/math].

LPSolve(a+b+c+d+e+d/2,{op(Y4),a+b+c+d+e<=40},assume=nonnegint,depthlimit=100,maximize);

[85/2, [a = 8, b = 16, c = 11, d = 5, e = 0]]

LPSolve(a+b+c+d+e+d/2,{op(Y4),e=1},assume=nonnegint,depthlimit=100,maximize);

                [81/2, [a = 8, b = 15, c = 12, d = 3, e = 1]]

This, together with the 4D data for 41+ point Moser sets, implies that [math]\displaystyle{ a+b+c+d+e+d/2+5e/2 \leq 43 }[/math].

X4 := {op(X4), A4+4*e <= 43, A4 + 4*d + 5*e/2 <= 43};

X5 := {op(X4), op(subs([a=b,b=c,c=d,d=e,e=f],X4)), 2*a+f <= 2};

Y5 := subs([a=a/32,b=b/80,c=c/80,d=d/40,e=e/10],X5);

LPSolve(a+b+c+d+e+f,{op(Y5),f=1},assume=nonnegint,depthlimit=100,maximize);

[119, [a = 16, b = 40, c = 40, d = 19, e = 3, f = 1]]

This, together with the bound [math]\displaystyle{ c'_5=124 }[/math], implies that [math]\displaystyle{ a+b+c+d+e+f+5f \leq 124 }[/math].

X5 := {op(X5), A5+5*f <= 124};

X6 := {op(X5), op(subs([a=b,b=c,c=d,d=e,e=f,f=g],X5)), op(subs([b=d,c=g],X2)), op(subs([b=c,c=e,d=g],X3))};

Y6 := subs([a=a/64,b=b/192,c=c/240,d=d/160,e=e/60,f=f/12],X6);

LPSolve(a+b+c+d+e+f+g,Y6,assume=nonnegint,depthlimit=100,maximize);

[360, [a = 29, b = 87, c = 134, d = 97, e = 8, f = 5, g = 0]]

LPSolve(a+b+c+d+e+f+g,{op(Y6),g=1},assume=nonnegint,depthlimit=100,maximize);

[354, [a = 27, b = 96, c = 120, d = 80, e = 26, f = 4, g = 1]]

This implies that [math]\displaystyle{ a+b+c+d+e+f+g+6g \leq 360 }[/math].

LPSolve(a+b+c+d+e+f+g,{op(Y6),e=0,f=0,g=0},assume=nonnegint,depthlimit=100,maximize);

[356, [a = 24, b = 72, c = 180, d = 80, e = 0, f = 0, g = 0]]

X6 := {op(X6), A6+6*g <= 360};

X7 := {op(X6), op(subs([a=b,b=c,c=d,d=e,e=f,f=g,g=h],X6)), 2*a+h <= 2};

Y7 := subs([a=a/128,b=b/448,c=c/672,d=d/560,e=e/280,f=f/84,g=g/14],X7);

LPSolve(a+b+c+d+e+f+g+h,Y7,assume=nonnegint,depthlimit=100,maximize);

[1075, [a = 65, b = 214, c = 312, d = 301, e = 146, f = 32, g = 5, h = 0]]

LPSolve(a+b+c+d+e+f+g+h,{op(Y7),h=1},assume=nonnegint,depthlimit=100,maximize);

[1069, [a = 62, b = 216, c = 336, d = 280, e = 140, f = 30, g = 4, h = 1]]