Maple calculations

The computations below were done in Maple 12. The parameters a, b, c, etc. are initially the Behrend sphere densities (e.g. a is the proportion of points with no 2s that lie in the set), but when one converts from the X's to the Y's, they are the Behrend sphere counts (i.e. a is now the number of points with no 2s that lie in the set).

with(Optimization);

A3 := 8*a + 12*b + 6*c + d;

A4 := 16*a+32*b+24*c+8*d+e;

A5 := 32*a+80*b+80*c+40*d+10*e+f;

A6 := 64*a+192*b+240*c+160*d+60*e+12*f+g;

A7 := 128*a+448*b+672*c+560*d+280*e+84*f+14*g+h;

X1 := {2*a+b <= 2, b <= 1};

X2 := {4*a+2*b+c <= 4, 2*a+c <= 2, 2*b+c <= 2, c <= 1};

X3 := {op(X2), op(subs([a=b,b=c,c=d],X2)), 2*a+d <= 2};

These are the inequalities inherited from xy1, xy2, xxx cubes (averaged over symmetries)

Y3 := subs([a=a/8,b=b/12,c=c/6,d=d],X3);

LPSolve(a+b+c+d,Y3,assume=nonnegint,depthlimit=100,maximize);

[16, [a = 4, b = 6, c = 6, d = 0]]

This gives a proof of [math]\displaystyle{ c'_3 \leq 16 }[/math].

X3 := {op(X3), 8*a+6*b+6*c+2*d<=11, 4*a+4*b+3*c+d<=6, 7*a+3*b+3*c+d <= 7, 4*a+6*c+2*d<=7, 5*a+3*c+d<=5};

This comes from the linear inequalities obeyed by the 3D extremals.

X4 := {op(X3), op(subs([a=b,b=c,c=d,d=e],X3)), op(subs([b=c,c=e],X2))};

The op(subs([b=c,c=e],X2) term here reflects the presence of diagonal 2D cubes such as xxyy in 4D with two appearances of each wildcard.

X4 := {op(X4),4*a+2*b+3*c+2*d+e <= 6, 8*a+2*b+3*c+2*d+e <= 8};

These come from the xxyz slices, see Peake.986 or Peake.993

Y4 := subs([a=a/16,b=b/32,c=c/24,d=d/8],X4);

LPSolve(a+b+c+d+e,Y4,assume=nonnegint,depthlimit=100,maximize);

[44, [a = 4, b = 16, c = 24, d = 0, e = 0]]

off by one! The true maximum is of course [math]\displaystyle{ c'_4=43 }[/math]. But one can eliminate the above 44-point set by hand

LPSolve(a+b+c+d+e,{op(Y4),e=1},assume=nonnegint,depthlimit=100,maximize);

[39, [a = 8, b = 16, c = 12, d = 2, e = 1]]

off by three, thanks to the 4D Moser brute force search. So we have [math]\displaystyle{ a+b+c+d+e+7e \leq 43 }[/math].

LPSolve(c,{op(Y4),a+b+c+d+e=43},assume=nonnegint,depthlimit=100);

[18, [a = 5, b = 20, c = 18, d = 0, e = 0]]

This shows that 43-point sets have c at least 18.

LPSolve(c,{op(Y4),a+b+c+d+e>=42},assume=nonnegint,depthlimit=100);

[12, [a = 6, b = 24, c = 12, d = 0, e = 0]]

This shows that 42+ point sets have c at least 12

LPSolve(d,{op(Y4),a+b+c+d+e >= 41},assume=nonnegint,depthlimit=100,maximize);

[4, [a = 7, b = 17, c = 13, d = 4, e = 0]]

This shows that 41+ point Moser sets have d at most 4. Off by 1 again: the truth here is d=3

LPSolve(d,{op(Y4),a+b+c+d+e >= 40},assume=nonnegint,depthlimit=100,maximize);

[6, [a = 8, b = 16, c = 10, d = 6, e = 0]]

This shows that 40+ point Moser sets have d at most 6.

LPSolve(a+b+c+d+e+d/2,{op(Y4),a+b+c+d+e<=40},assume=nonnegint,depthlimit=100,maximize);

[43, [a = 8, b = 16, c = 10, d = 6, e = 0]]

LPSolve(a+b+c+d+e+d/2,{op(Y4),e=1},assume=nonnegint,depthlimit=100,maximize);

[40, [a = 8, b = 16, c = 12, d = 2, e = 1]]

off by 2.5, thanks to the 4D Moser brute force search. So we have [math]\displaystyle{ a+b+c+d+e+d/2+11e/2 \leq 43 }[/math].

X4 := {op(X4), A4+7*e <= 43, A4 + d/2 + 11*e/2 <= 43};

X5 := {op(X4), op(subs([a=b,b=c,c=d,d=e,e=f],X4)), 2*a+f <= 2};

xyzw1, xyzw2, and xxxx cube inequalities

X5 := {op(X5), 4*a+b+2*c+2*d+e+f <= 11/2, 2*e+f <= 2, 4*a+4*c+2*d+e+f <= 6, 4*a+2*b+2*c+2*d+e+f <= 6, 7*a+b+2*c+2*d+e+f <= 7, 4*a+2*e+f <= 4, 8*a+4*c+2*d+e+f <= 8, 8*a+2*b+2*c+2*d+e+f <= 8, 4*a+2*b+2*d+2*e+f <= 6, 8*a+2*b+2*d+2*e+f <= 8};

These inequalities come from xxyyz cubes, see Peake.989

X5 := {op(X5),8*a+4*b+2*c+2*d+4*e+2*f <=11,4*a+2*b+1*c+2*d+2*e+1*f <= 6,0*a+0*b+2*c+0*d+0*e+1*f <= 2,4*a+4*b+1*c+0*d+2*e+1*f <= 6,7*a+2*b+1*c+1*d+2*e+1*f <= 7,8*a+2*b+1*c+2*d+2*e+1*f <= 8,4*a+0*b+2*c+0*d+0*e+1*f <= 4,4*a+0*b+2*c+2*d+2*e+1*f <= 6,8*a+0*b+2*c+2*d+2*e+1*f <= 8,8*a+4*b+1*c+0*d+2*e+1*f <= 8};

These inequalities come from xxxyz cubes, see Peake.991

Y5 := subs([a=a/32,b=b/80,c=c/80,d=d/40,e=e/10],X5);

LPSolve(a+b+c+d+e+f,Y5,assume=nonnegint,depthlimit=100,maximize);

[126, [a = 10, b = 38, c = 70, d = 8, e = 0, f = 0]]

Off by two! The truth is [math]\displaystyle{ c'_5=124 }[/math]. But the 126 case can again be eliminated by hand

LPSolve(a+b+c+d+e+f,{op(Y5),f=1},assume=nonnegint,depthlimit=100,maximize);

[115, [a = 16, b = 40, c = 40, d = 17, e = 1, f = 1]]

This, together with the bound [math]\displaystyle{ c'_5=124 }[/math], implies that [math]\displaystyle{ a+b+c+d+e+f+9f \leq 124 }[/math].

X5 := {op(X5), A5+9*f <= 124};

LPSolve(a+b+c+d+e+f,{op(Y5),e>=1},assume=nonnegint,depthlimit=100,maximize);

[125, [a = 11, b = 36, c = 68, d = 9, e = 1, f = 0]]

LPSolve(d,{op(Y5),a+b+c+d+e=125},assume=nonnegint,depthlimit=100,maximize);

[12, [a = 11, b = 35, c = 67, d = 12, e = 0, f = 0]]

Not good at all... we were able to get d=0 for 125-sets.

LPSolve(d,{op(Y5),a+b+c+d+e=126},assume=nonnegint,depthlimit=100,maximize);

[8, [a = 10, b = 37, c = 71, d = 8, e = 0, f = 0]]

X6 := {op(X5), op(subs([a=b,b=c,c=d,d=e,e=f,f=g],X5)), op(subs([b=d,c=g],X2)), op(subs([b=c,c=e,d=g],X3))};

xyzwu1, xyzwu2, xxxyyy, xxyyzz cube inequalities

X6 := {op(X6),8*a+4*b+2*c+2*e+4*f+2*g <= 11,0*a+0*b+2*c+0*e+0*f+1*g <= 2,4*a+2*b+1*c+2*e+2*f+1*g <= 6,7*a+2*b+1*c+1*e+2*f+1*g <= 7,4*a+0*b+2*c+0*e+0*f+1*g <= 4,4*a+0*b+2*c+2*e+2*f+1*g <= 6,8*a+0*b+2*c+2*e+2*f+1*g <= 8,8*a+2*b+1*c+2*e+2*f+1*g <= 8,4*a+4*b+1*c+0*e+2*f+1*g <= 6,8*a+4*b+1*c+0*e+2*f+1*g <= 8};

These come from xxxxyz cubes, see Peake.991

X6 := {op(X6),4*a+2*b+0*c+3*d+1*e+1*f+1*g <= 6,4*a+0*b+2*c+3*d+1*e+1*f+1*g <= 6,8*a+2*b+0*c+3*d+1*e+1*f+1*g <= 8,8*a+0*b+2*c+3*d+1*e+1*f+1*g <= 8,0*a+4*b+0*c+0*d+2*e+0*f+1*g <= 4,0*a+0*b+4*c+0*d+0*e+2*f+1*g <= 4,8*a+4*b+0*c+0*d+2*e+0*f+1*g <= 8,8*a+0*b+4*c+0*d+0*e+2*f+1*g <= 8};

These come from xxxyyz cubes, see Peake.991, Peake.993

Y6 := subs([a=a/64,b=b/192,c=c/240,d=d/160,e=e/60,f=f/12],X6);

LPSolve(a+b+c+d+e+f+g,Y6,assume=nonnegint,depthlimit=500,maximize);

[362, [a = 31, b = 84, c = 137, d = 86, e = 21, f = 3, g = 0]]

LPSolve(a+b+c+d+e+f+g,{op(Y6),g=1},assume=nonnegint,depthlimit=100,maximize);

[352, [a = 30, b = 96, c = 120, d = 80, e = 22, f = 3, g = 1]]

This implies that [math]\displaystyle{ a+b+c+d+e+f+g+10g \leq 362 }[/math].

LPSolve(a+b+c+d+e+f+g,{op(Y6),e=0,f=0,g=0},assume=nonnegint,depthlimit=100,maximize);

[360, [a = 32, b = 60, c = 132, d = 136, e = 0, f = 0, g = 0]]

X6 := {op(X6), A6+9*g <= 361};

X7 := {op(X6), op(subs([a=b,b=c,c=d,d=e,e=f,f=g,g=h],X6)), 2*a+h <= 2};

xyzwuv1, xyzwuv2, xxxxxxx inequalities

Y7 := subs([a=a/128,b=b/448,c=c/672,d=d/560,e=e/280,f=f/84,g=g/14],X7);

LPSolve(a+b+c+d+e+f+g+h,Y7,assume=nonnegint,depthlimit=500,maximize);

[1079, [a = 64, b = 214, c = 306, d = 321, e = 141, f = 31, g = 2, h = 0]]

LPSolve(a+b+c+d+e+f+g+h,{op(Y7),h=1},assume=nonnegint,depthlimit=100,maximize);

[1067, [a = 56, b = 224, c = 336, d = 280, e = 140, f = 28, g = 2, h = 1]]